Npc MVP invasion

[garro 0]

Hello community I found this npc of invasion that is mvps, but I would like for example if it left prontera to be invaded by the mvps, that the mvps are random, so that if afterwards it leaves jawaii they are not the same, and so on ,Thank you

inva.txt

Edited March 18, 2019 by AnnieRuru

[AnnieRuru 957]

Spoiler

-	script	simple invasion	FAKE_NPC,{
OnInit:
	setarray .mvp,
		ORK_HERO,            // 50
		MAYA,                // 55
		ORC_LORD,            // 55
		GOLDEN_BUG,          // 65
		EDDGA,               // 65
		OSIRIS,              // 68
		AMON_RA,             // 69
		PHREEONI,            // 71
		DRACULA,             // 75
		DOPPELGANGER,        // 77
		MISTRESS,            // 78
		MOONLIGHT,           // 79
		LADY_TANEE,          // 80
		BAPHOMET,            // 81
		PHARAOH,             // 85
		DRAKE,               // 91
		KNIGHT_OF_WINDSTORM, // 92
		BOITATA,             // 93
		LORD_OF_DEATH,       // 94
		LEAK,                // 94
		DARK_LORD,           // 96
		BACSOJIN_,           // 97
		GARM,                // 98
		KTULLANUX,           // 98
		THANATOS,            // 99
		INCANTATION_SAMURAI, // 100
		RSX_0806,            // 100
		DARK_SNAKE_LORD,     // 105
		TURTLE_GENERAL,      // 110
		TAO_GUNKA,           // 110
		ATROCE,              // 113
		S_NYDHOG,            // 117
		KRAKEN,              // 124
		KIEL_,               // 125
		APOCALIPS_H,         // 128 (Vesper)
		DETALE,              // 135
		FALLINGBISHOP,       // 138
		GLOOMUNDERNIGHT,     // 139
		QUEEN_SCARABA,       // 140
		PYURIEL,             // 141
		RANDGRIS,            // 141
		B_YGNIZEM,           // 141
		DAEHYON,             // 142
		KADES,               // 143
		IFRIT,               // 146
		GIOIA,               // 146
		BEELZEBUB_,          // 147
		FACEWORM_QUEEN,      // 155
		B_SEYREN,            // 160
		B_EREMES,            // 160
		B_HARWORD,           // 160
		B_MAGALETA,          // 160
		B_SHECIL,            // 160
		B_KATRINN,           // 160
		TIMEHOLDER;          // 170
	setarray .towns$,
		"prontera",
		"izlude",
		"moc_ruins",
		"geffen",
		"payon",
		"pay_arche",
		"alberta",
		"aldebaran",
		"yuno",
		"lighthalzen",
		"einbroch",
		"einbech",
		"comodo",
		"umbala",
		"amatsu",
		"gonryun",
		"ayothaya",
		"louyang",
		"hugel",
		"rachel",
		"veins",
		"brasilis",
		"dicastes01",
		"mora",
		"dewata",
		"malangdo",
		"malaya",
		"eclage";
	.mvpsize = getarraysize(.mvp);
	.townsize = getarraysize(.towns$);
//	bindatcmd "invade", strnpcinfo(NPC_NAME)+"::OnClock1600";
	end;
OnClock1600:
	.@mvp = .mvp[ rand(.mvpsize) ];
	.@town$ = .towns$[ rand(.townsize) ];
	monster .@town$, 0,0, "--ja--", .@mvp, 1, strnpcinfo(NPC_NAME)+"::Onkill";
	announce sprintf( _$( "An MVP [%s] rampaging in [%s] town !!" ), getmonsterinfo( .@mvp, MOB_NAME ), .@town$ ), bc_all, C_RED;
	end;
Onkill:
	announce sprintf( _$( "The player [%s] has dealt the final blow to the invasion boss ..." ), strcharinfo(PC_NAME) ), bc_all, C_LIME;
	// haiz...  still don't support killedrid from monster event label
	end;
}