Jump to content
  • Sign Up

MikZ

Members
 View Profile  See their activity

  • Content Count

    461

  • Joined

  • Last visited

Posts posted by MikZ

  5. Posted

    Good day!

    How can I remove Emperium HP during WOE?

     

    by default:

    // Show hp bar on monsters? (Default: yes)
    // NOTE: only works on client 2012-04-04aRagexeRE onwards
    show_monster_hp_bar: true
     

    But just wanted for Emperium only not to all monsters. thanks!

  6. Posted

    Good day!

    I tried using this script from rathena.

    all works fine. is just that im getting error 

    image.png.8e9302866f326d790551ca4d79c7bc69.png

    and I don't know how to fix this. please help.

      

    //===== rAthena Script =======================================
//= Devil Square
//===== By: ==================================================
//= Kirlein, Stillhard (translation), AnnieRuru (rewrite)
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= Devil Square, based on the event in MU Online.
//= Defeat three waves of monsters for treasure.
//===== Additional Comments: =================================
//= 1.0 First version, edited. [Euphy]
//============================================================

prontera,193,162,5	script	Devil Square Guardian#1	2_MONEMUS,{
	set .@gm_level, 99; // GM level required to start/stop the event

	mes "[Devil Square Guardian]";
	mes "This is the entrance to ^FF0000Devil Square^000000.";
	mes "If you fail or die, the door will close and you must wait until the event starts again to re-enter.";
	next;
	switch(select("Enter.:Information.:" + ((getgmlevel() >= .@gm_level) ? "GM Menu." : "") + ":Cancel.")) {
	case 1:
		if (.start != 1) { // registration period
			mes "[Devil Square Guardian]";
			mes "Devil Square is now closed.";
			mes "It will open at these times:";
			mes "00:00 , 02:00 , 04:00 , 06:00"; // display your times here
			mes "08:00 , 10:00 , 12:00 , 14:00";
			mes "16:00 , 18:00 , 20:00 , 22:00";
			close;
		}
		if (BaseLevel < 70 || Zeny < 20000) { // requirements
			mes "[Devil Square Guardian]";
			mes "You do not meet the requirements to enter Devil Square.";
			mes " ";
			mes "Requirements:";
			mes " - Base Level 70";
			mes " - Registration fee 20,000z";
			close;
		}
		Zeny -= 20000;
		announce strcharinfo(0)+" has entered Devil Square.", bc_npc;
		percentheal 100,100;
		warp "ordeal_1-1",183,182;
		close;
	case 2:
		mes "[Devil Square Guardian]";
		mes "Inside, you will encounter 3 waves of monsters. The monsters will grow stronger with each wave.";
		next;
		mes "[Devil Square Guardian]";
		mes "If you defeat all the enemies, you will be given the opportunity to open 10 Treasure Chests with items, equipment, and rare cards inside!";
		close;
	case 3:
		mes "[Devil Square Guardian]";
		switch (.start) { // event states
			case 0: mes "Devil Square has not yet started."; break;
			case 1: mes "Devil Square is currently accepting participants."; break;
			case 2: mes "Devil Square Event is currently running on Round "+ .round +" with "+ .mob +" monsters remaining."; break;
		}
		next;
		switch(select("Start event.:Stop event.:Cancel.")) {
		case 1:
			mes "[Devil Square Guardian]";
			if (.start)
				mes "Devil Square has already started.";
			else {
				mes "Starting Devil Square...";
				donpcevent strnpcinfo(0)+"::OnStartEvent";
			}
			close;
		case 2:
			mes "[Devil Square Guardian]";
			if (!.start)
				mes "Devil Square has not yet started.";
			else {
				mes "Stopping Devil Square...";
				donpcevent strnpcinfo(0)+"::OnStopEvent";
			}
			close;
		case 3:
			break;
		}
		break;
	case 4:
		break;
	}
	mes "[Devil Square Guardian]";
	mes "Farewell.";
	close;

OnStartEvent:
OnClock0000:
OnClock0200:
OnClock0400:
OnClock0600:
OnClock0800:
OnClock1000:
OnClock1200:
OnClock1400:
OnClock1600:
OnClock1800:
OnClock2000:
OnClock2200:
	.start = 1;
//	disablenpc "ord11-12"; //from npc/warps/pvp.txt
	disablenpc "Devil Square Guardian#2";
	mapannounce "ordeal_1-1","Devil Square is now closed.", bc_map;
	getmapxy .@map$, .@x, .@y, BL_NPC;
	mapwarp "ordeal_1-1", .@map$, .@x, .@y;
	killmonsterall "ordeal_1-1";
	announce "Devil Square is OPEN. The event will begin in 5 minutes.", bc_all;
	sleep 6000;
	announce "Devil Square will begin in 4 minutes.", bc_all;
	sleep 6000;
	announce "Devil Square will begin in 3 minutes.", bc_all;
	sleep 6000;
	announce "Devil Square will begin in 2 minutes.", bc_all;
	sleep 6000;
	announce "Devil Square will begin in 1 minute.", bc_all;
	sleep 6000;
	announce "Devil Square has STARTED!", bc_all;
	if ( !getmapusers("ordeal_1-1") )
		goto OnStopEvent;
	.start = 2;
	.round = 1;
	.mob = 75;
	areamonster "ordeal_1-1",132,137,167,159,"[DS] SOLDIER SKELETON",1028,10,strnpcinfo(0)+"::OnDevilDead";
	areamonster "ordeal_1-1",132,137,167,159,"[DS] ORC ARCHER",1189,15,strnpcinfo(0)+"::OnDevilDead";
	areamonster "ordeal_1-1",132,137,167,159,"[DS] SANDMAN",1165,10,strnpcinfo(0)+"::OnDevilDead";
	areamonster "ordeal_1-1",132,137,167,159,"[DS] ARCHER SKELETON",1016,15,strnpcinfo(0)+"::OnDevilDead";
	areamonster "ordeal_1-1",132,137,167,159,"[DS] MINOROUS",1149,15,strnpcinfo(0)+"::OnDevilDead";
	areamonster "ordeal_1-1",132,137,167,159,"[DS] REQUIEM",1164,10,strnpcinfo(0)+"::OnDevilDead";
	end;

OnDevilDead:
	.mob--;
	if ( .mob == 25 || .mob == 5 )
		announce "Devil Square : "+ .mob +" monsters remaining in round 1.", bc_map;
	else if ( .mob <= 0 ) {
		announce "Devil Square is entering round 2...", bc_map;
		goto OnDevil2;
	}
	end;

OnDevil2:
	.round = 2;
	.mob = 70;
	areamonster "ordeal_1-1",54,54,110,110,"[DS] GARGOYLE",1253,15,strnpcinfo(0)+"::OnDevilDead2";
	areamonster "ordeal_1-1",54,54,110,110,"[DS] ALARM",1193,10,strnpcinfo(0)+"::OnDevilDead2";
	areamonster "ordeal_1-1",54,54,110,110,"[DS] HIGH ORC",1213,10,strnpcinfo(0)+"::OnDevilDead2";
	areamonster "ordeal_1-1",54,54,110,110,"[DS] INJUSTICE",1257,10,strnpcinfo(0)+"::OnDevilDead2";
	areamonster "ordeal_1-1",54,54,110,110,"[DS] MIMIC",1191,15,strnpcinfo(0)+"::OnDevilDead2";
	areamonster "ordeal_1-1",54,54,110,110,"[DS] WRAITH",1192,10,strnpcinfo(0)+"::OnDevilDead2";
	end;

OnDevilDead2:
	.mob--;
	if ( .mob == 25 || .mob == 5 )
		announce "Devil Square : "+ .mob +" monsters remaining in round 2.", bc_map;
	else if ( .mob <= 0 ) {
		announce "Devil Square is entering round 3...", bc_map;
		goto OnDevil3;
	}
	end;

OnDevil3:
	.round = 3;
	.mob = 58;
	areamonster "ordeal_1-1",183,182,246,244,"[DS] ANOLIAN",1206,15,strnpcinfo(0)+"::OnDevilDead3";
	areamonster "ordeal_1-1",183,182,246,244,"[DS] WANDERER",1208,15,strnpcinfo(0)+"::OnDevilDead3";
	areamonster "ordeal_1-1",183,182,246,244,"[DS] DEVIRUCHI",1109,10,strnpcinfo(0)+"::OnDevilDead3";
	areamonster "ordeal_1-1",183,182,246,244,"[DS] JOKER",1131,15,strnpcinfo(0)+"::OnDevilDead3";
	areamonster "ordeal_1-1",183,182,246,244,"[DS] MOONLIGHT",1150,2,strnpcinfo(0)+"::OnDevilDead3";
	areamonster "ordeal_1-1",183,182,246,244,"[DS] DARK ILLUSION",1302,1,strnpcinfo(0)+"::OnDevilDead3";
	end;

OnDevilDead3:
	.mob--;
	if ( .mob == 25 || .mob == 5 )
		announce "Devil Square : "+ .mob +" monsters remaining in the final round.", bc_map;
	else if ( .mob <= 0 ) {
		announce "Devil Square : CONGRATULATIONS. These 10 Treasure Chests are yours.", bc_map;
		goto OnDevil4;
	}
	end;

OnDevil4:
	.round = 4;
	.mob = 10;
	monster "ordeal_1-1",0,0,"Treasure Chest",1357,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,"Treasure Chest",1351,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1353,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1335,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1325,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1943,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1939,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1352,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1356,1,strnpcinfo(0)+"::OnTreasureDead";
	monster "ordeal_1-1",0,0,,"Treasure Chest",1360,1,strnpcinfo(0)+"::OnTreasureDead";
	end;

OnTreasureDead:
	.mob--;
	announce "Devil Square : "+ strcharinfo(0) +" has opened the Treasure Chest at Devil Square.", bc_all;
	getitem	 F_Rand( 7227, 12210, 12103, 14003, 12913, 12914, 25046, 25047), 1;
	if ( .mob <= 0 )
		goto OnStopEvent;
	end;

OnStopEvent:
	killmonsterall "ordeal_1-1";
	//enablenpc "ord11-12"; //from npc/warps/pvp.txt
	enablenpc "Devil Square Guardian#2";
	.start = .round = .mob = 0;
	end;
}

ordeal_1-1,149,149,7	script	Devil Square Guardian#2	4_F_LUCILE,{
	mes "[Exit]";
	mes "Farewell.";
	getitem 7227,5;
	close2;
	warp "prontera",156,184;
	end;
}

ordeal_1-1	mapflag	nowarp
ordeal_1-1	mapflag	nowarpto
ordeal_1-1	mapflag	noteleport
ordeal_1-1	mapflag	monster_noteleport
ordeal_1-1	mapflag	nosave	SavePoint
ordeal_1-1	mapflag	nomemo
ordeal_1-1	mapflag	nobranch
ordeal_1-1	mapflag	nopenalty
ordeal_1-1	mapflag	noicewall
ordeal_1-1	mapflag	noloot

     

  7. Posted

    On 8/20/2019 at 3:05 PM, Cretino said:

    Hey guys, I was testing my script in the latest Hercules revision and realized it had stopped working...
    So I made some updates in script and source code to work again and also with some bug fixes.

    If have any bug, report to me for trying fix.

    New script and source modification in first post.

    @TOPIC

    Version: 1.2 (Updated script and source modification to work with last Hercules revision [Cretino] (Need source modification))



    Do you have plugin?

  9. Posted

    4 hours ago, meko said:

    From the error it appears that FluxCP is trying to connect to your mysql server but fails to reach it and the connection times out. You may have forgotten to update the DbConfig.Hostname when you moved to your new host



    Hi @meko, Already did that. 

    			<?php
return array(
	// Example server configuration. You may have more arrays like this one to
	// specify multiple server groups (however they should share the same login
	// server whilst they are allowed to have multiple char/map pairs).
	array(
		'ServerName'     => 'Test',
		// Global database configuration (excludes logs database configuration).
		'DbConfig'       => array(
			//'Socket'     => '/tmp/mysql.sock',
			//'Port'       => 3306,
			//'Encoding'   => 'utf8', // Connection encoding -- use whatever here your MySQL tables collation is.

			'Convert'    => 'utf8',
				// -- 'Convert' option only works when 'Encoding' option is specified and iconv (http://php.net/iconv) is available.
				// -- It specifies the encoding to convert your MySQL data to on the website (most likely needs to be utf8)
			'Hostname'   => '1**.**.**.**',
			'Username'   => 'Test',
			'Password'   => 'Test01',
			'Database'   => 'Test',
			'Persistent' => true,
			'Timezone'   => null // Example: '+0:00' is UTC.
			// The possible values of 'Timezone' is as documented from the MySQL website:
			// "The value can be given as a string indicating an offset from UTC, such as '+10:00' or '-6:00'."
			// "The value can be given as a named time zone, such as 'Europe/Helsinki', 'US/Eastern', or 'MET'." (see below continuation!)
			// **"Named time zones can be used only if the time zone information tables in the mysql database have been created and populated."
		),
		// This is kept separate because many people choose to have their logs
		// database accessible under different credentials, and often on a
		// different server entirely to ensure the reliability of the log data.
		'LogsDbConfig'   => array(
			//'Socket'     => '/tmp/mysql.sock',
			//'Port'       => 3306,
			//'Encoding'   => null, // Connection encoding -- use whatever here your MySQL tables collation is.
			'Convert'    => 'utf8',
				// -- 'Convert' option only works when 'Encoding' option is specified and iconv (http://php.net/iconv) is available.
				// -- It specifies the encoding to convert your MySQL data to on the website (most likely needs to be utf8)
			'Hostname'   => '1**.**.**.**',
			'Username'   => 'Test',
			'Password'   => 'Test01',
			'Database'   => 'Test',
			'Persistent' => true,
			'Timezone'   => null // Possible values is as described in the comment in DbConfig.
		),
		// Login server configuration.
		'LoginServer'    => array(
			'Address'  => '1**.**.**.**',
			'Port'     => 6900,
			'UseMD5'   => false,
			'NoCase'   => true, // Hercules account case-sensitivity; Default: Case-INsensitive (true).
			'GroupID'  => 0,    // Default account group ID during registration.
			//'Database' => 'ragnarok'
		),

     

  10. Posted

    Good day!

    I recently transfer my VPS to other hosting sites.
    And upon changing the IP address in my Fluxcp everything works fine except account creation. It say Uh oh, what happened?

    Did some googling and I end up getting these errors.

      

    [2020-05-09 01:57:11] (PDOException) Exception PDOException: SQLSTATE[HY000] [2002] Connection timed out
[2020-05-09 01:57:11] (PDOException) **TRACE** #0 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Connection.php(81): PDO->__construct('mysql:host=192....', 'Test', 'TestPass*', Array)
[2020-05-09 01:57:11] (PDOException) **TRACE** #1 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Connection.php(94): Flux_Connection->connect(Object(Flux_Config))
[2020-05-09 01:57:11] (PDOException) **TRACE** #2 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Connection.php(159): Flux_Connection->getConnection()
[2020-05-09 01:57:11] (PDOException) **TRACE** #3 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/LoginServer.php(179): Flux_Connection->getStatement('SELECT userid F...')
[2020-05-09 01:57:11] (PDOException) **TRACE** #4 /homepages/19/d739599868/htdocs/LibRO/modules/account/create.php(32): Flux_LoginServer->register('test0000', 'TestPass01', 'TestPass01', '[email protected]...', 'M', '2020-05-09', 'uVEIp')
[2020-05-09 01:57:11] (PDOException) **TRACE** #5 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Template.php(375): include('/homepages/19/d...')
[2020-05-09 01:57:11] (PDOException) **TRACE** #6 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Dispatcher.php(170): Flux_Template->render()
[2020-05-09 01:57:11] (PDOException) **TRACE** #7 /homepages/19/d739599868/htdocs/LibRO/index.php(173): Flux_Dispatcher->dispatch(Array)
[2020-05-09 01:57:11] (PDOException) **TRACE** #8 {main}
[2020-05-09 01:57:15] (PDOException) Exception PDOException: SQLSTATE[HY000] [2002] Connection timed out
[2020-05-09 01:57:15] (PDOException) **TRACE** #0 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Template.php(375): include()
[2020-05-09 01:57:15] (PDOException) **TRACE** #1 /homepages/19/d739599868/htdocs/LibRO/lib/Flux/Dispatcher.php(170): Flux_Template->render()
[2020-05-09 01:57:15] (PDOException) **TRACE** #2 /homepages/19/d739599868/htdocs/LibRO/index.php(173): Flux_Dispatcher->dispatch(Array)
[2020-05-09 01:57:15] (PDOException) **TRACE** #3 {main}

    What does these errors means?

  13. Posted

    On 2/12/2017 at 7:40 AM, Ridley said:

    File Name: @itemall and @itemmap

    File Submitter: Ridley

    File Submitted: 12 Feb 2017

    File Category: Utility

     

    Give an item to all players online

    @itemall <Item ID> <Item Amount>

    
@itemall <Item ID> <Item Amount>
     

     

     

    Give an item to all players on the same map as you

    @itemmap <Item ID> <Item Amount>

    
@itemmap <Item ID> <Item Amount>
     

     

     

    Using some old code from Emistry for this, thank you for your permission to use it.

     

    Click here to download this file


    Good day!

    Is there a way to make it per last_unique_id (gepard)?

    Thanks!

  14. Posted

    Good day!

    My I request please.
    How to change this charip to char unique ID? thanks!

      

    OnReward:
	set .@sql$, ((.Options&4)?"position = 0":"online = 1");
	if (.Options&2) set .@str$,gettimestr("%B %d, %Y",21);
	freeloop(1);
	for(set .@i,0; .@i<30; set .@i,.@i+1)
		if (getarg(0)&(1<<.@i)) {
			set .@GID, getcastledata(.Castles$[.@i],1);
			if (!.@GID) continue;
			set .@size, query_sql("SELECT account_id,char_id FROM `guild_member` WHERE guild_id = '"+.@GID+"' AND "+.@sql$,.@aid,.@cid);
			for(set .@j,0; .@j<.@size; set .@j,.@j+1) {
				if (.Options&8 && !(.Options&4)) {
					set .@ip$, replacestr(getcharip(.@aid[.@j]),".","a");
					if (getd(".@ip_"+.@i+"_"+.@ip$)) continue;
					setd ".@ip_"+.@i+"_"+.@ip$,1;
				}

     

     

  15. Posted

    Good day!

    I place the battle ground armors[1] in @bgshop by dastgir, I thought would still give slotted to it. Cuz it was to good to see name of battleground in the item but unfortunately it remove the slots of the items.


    May I request a script to read those name item and to convert back to badges?? I have players who already bought the items.

  16. Posted · Edited by MikZ

    13 hours ago, meko said:

    Running with root privileges is inherently insecure and so Hercules will complain when trying to start as the root user.

    You must create a new user and run Hercules under that new user (preferably as a daemon).

     

    To run a command with sudo your user must be in the sudoers file (you can edit it with visudo) but keep in mind that Hercules will also warn you when running with sudo (since it runs as root).

    I am sorry i am really not good at it. I am running a non-ro hosting.
    While transferring i did this


    useradd --create-home --shell /bin/bash hercules1234

    passwd hercules1234

     

    then:

     

    su hercules1234

    vncserver

    vncpasswd

     

    then:

     

    transfer the files under hercules1234 user

    all files where being transfer under hercules1234 user

     

    created new user(hercphp) with root privileges in mysql.

     

    login to mysql -u hercphp

    upload  sql

     

    then su hercules1234
    go to trunk ./athena.-start start. works fine. but upon login. disconnect to login-server

    What did i missed?

     

    Does the unzipping gives root privileges? 

     

  23. Posted

    Good day!

    I am using this Warper script and disabled the warp to sograt 21 at 22.
    Can you help me how to only enable it to character who finished the quest of wounded morroc? Yes, only character who finished the quest.

    Thanks!

      

    //===== Hercules Script ======================================
//= Warper
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.4b
//===== Description: =========================================
//= A complete - but very condensed - warper script.
//= Some coordinates written by Tekno-Kanix and ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.1 Added missing duplicates and fixed coordinates.
//= 1.2 Added new episodes and simplified functions.
//= 1.3 Added Renewal checks and Instances menu.
//=     Aligned coordinates with @go.
//= 1.4 Added new Guild Dungeons.
//= 1.4a Slight edits.
//= 1.4b Added Wolfchev's Laboratory warp.
//============================================================

-	script	Warper	-1,{

function Go; function Disp; function Pick; function Restrict;
// --------------------------------------------------
//	Main Menu:
// --------------------------------------------------

menu
	//	"Last Warp ^777777["+lastwarp$+"]^000000",-,
    	" ~ Towns",Towns,
    	" ~ Fields",Fields,
    	" ~ Dungeons",Dungeons;
    	//" ~ Guild Castles",Castles,
    	//" ~ Guild Dungeons",Guild_Dungeons,
    	//" ~ Instances",Instances,
    	//" ~ Special Areas",Special;
		

	if (lastwarp$ == "")
		message strcharinfo(0),"You haven't warped anywhere yet.";
	else
		warp lastwarp$,lastwarpx,lastwarpy;
	end;

// ------------------- Functions -------------------
// * Go("<map>",<x>,<y>);
//	~ Warps directly to a map.
//
// * Disp("<Menu Option>",<first option>,<last option>);
// * Pick("<map_prefix>"{,<index offset>});
//	~ Dynamic menu and map selection (auto-numbered).
//	~ Fields and Dungeons must use Disp and Pick Functions.
//
// * Disp("<Option 1>:<Option 2>:<etc.>");
// * Pick("","<map1>","<map2>","<etc.>");
//	~ Manual menu and map selection (listed).
//
// * Restrict("<RE | Pre-RE>"{,<menu option numbers>});
//	~ Only allows map for Renewal or Pre-Renewal modes.
//     If menu option numbers are given, only those maps
//     will be restricted (i.e. not for "Go").
//
// Other notes:
//   ~ Array @c[] holds all (x,y) coordinates.
//   ~ Use @c[2] EXCEPT when maps begin dynamically
//	  at 0: use @c[0] and Pick() offset 1.
// --------------------------------------------------

function Go {
	set lastwarp$, getarg(0);
	set lastwarpx, getarg(1,0);
	set lastwarpy, getarg(2,0);
	warp getarg(0),getarg(1,0),getarg(2,0);
	end;
}
function Disp {
	if (getargcount() < 3)
		set @menu$, getarg(0);
	else {
		set @menu$,"";
		for (set .@i,getarg(1); .@i<=getarg(2); set .@i,.@i+1)
			set @menu$, @menu$+getarg(0)+" "+.@i+":";
	}
	return;
}
function Pick {
	set .@warp_block,@warp_block;
	set @warp_block,0;
	if((@f && .OnlyFirstFld) || (@d && .OnlyFirstDun)){
		set .@select,1;
		if(.@warp_block){
			while(.@warp_block & (1<<.@select)){
				.@select += 1;
			}
		}
	}else{
		set .@select, select(@menu$);
	}
	if (getarg(0) == "") {
		set .@i, .@select;
		set .@map$, getarg(.@i);
	} else {
		set .@i, .@select-getarg(1,0);
		set .@map$, getarg(0)+((.@i<10)?"0":"")+.@i;
	}
	if (.@warp_block & (1<<.@select)) {
		message strcharinfo(0),"Sorry! Warp to MVP locations are disabled.";
		close;
		return;
	}
	set .@x, @c[.@i*2];
	set .@y, @c[.@i*2+1];
	deletearray @c[0],getarraysize(@c);
	@f = false; @d = false;
	Go(.@map$,.@x,.@y);
}
function Restrict {
	if ((getarg(0) == "RE" && !RENEWAL) || (getarg(0) == "Pre-RE" && RENEWAL)) {
		if (getarg(1,0)) {
			set @warp_block,0;
			for (set .@i,1; .@i<getargcount(); set .@i,.@i+1)
				set @warp_block, @warp_block | (1<<getarg(.@i));
		} else {
			message strcharinfo(0),"Sorry! Warp to MVP locations are disabled.";
			close;
			return;
		}
	}
	return;
}

// --------------------------------------------------
	Towns:
// --------------------------------------------------
menu	"Prontera",T1, "Alberta",T2, "Aldebaran",T3, "Amatsu",T4, "Ayothaya",T5,
    	"Comodo",T7, "Einbech",T10, 
    	"Einbroch",T11,"Geffen",T13, "Gonryun",T14, "Hugel",T15,
    	"Izlude",T16, "Jawaii",T17,"Lighthalzen",T19, "Louyang",T20,
		"Lutie",T21, "Manuk",T24,
		"Midgarts Expedition Camp",T25,  "Morroc",T27, "Moscovia",T28,
		"Nameless Island",T29, "Niflheim",T30, "Payon",T31, "Rachel",T32, "Splendide",T33,
		"Thor Camp",T34, "Umbala",T35, "Veins",T36, "Yuno",T37;
//"Brasilis",T6, "Mora",T26,
// "Dewata",T8, 
//"Eclage",T9,
 //"Lasagna",T18, 
// "El Dicastes",T12,
// "Malaya",T23, 
//
 // "Malangdo",T22, 

T1: Go("prontera",155,183);
T2: Go("alberta",28,234);
T3: Go("aldebaran",140,131);
T4: Go("amatsu",198,84);
T5: Go("ayothaya",208,166);
T6: Restrict("RE");
	Go("brasilis",196,217);
T7: Go("comodo",209,143);
T8: Restrict("RE");
	Go("dewata",200,180);
T9: Restrict("RE");
	Go("ecl_in01",48,53);
T10: Go("einbech",63,35);
T11: Go("einbroch",64,200);
T12: Restrict("RE");
	 Go("dicastes01",198,187);
T13: Go("geffen",119,59);
T14: Go("gonryun",160,120);
T15: Go("hugel",96,145);
T16: Go("izlude",128,(RENEWAL?146:114));
T17: Go("jawaii",251,132);
T18: Restrict("RE");
	 Go("lasagna",193,182);
T19: Go("lighthalzen",158,92);
T20: Go("louyang",217,100);
T21: Go("xmas",147,134);
T22: Restrict("RE");
	 Go("malangdo",140,114);
T23: Restrict("RE");
	 Go("malaya",231,200);
T24: Go("manuk",282,138);
T25: Go("mid_camp",210,288);
T26: Restrict("RE");
	 Go("mora",55,146);
T27: Go("morocc",156,93);
T28: Go("moscovia",223,184);
T29: Go("nameless_n",256,215);
T30: Go("niflheim",202,174);
T31: Go("payon",179,100);
T32: Go("rachel",130,110);
T33: Go("splendide",201,147);
T34: Go("thor_camp",246,68);
T35: Go("umbala",97,153);
T36: Go("veins",216,123);
T37: Go("yuno",157,51);

// --------------------------------------------------
	Fields:
// --------------------------------------------------
@f = true;
menu	"Amatsu Fields",F1, "Ayothaya Fields",F2, "Bifrost Fields", F3,
    	"Brasilis Fields",F4, "Comodo Fields",F5, "Dewata Fields",F6,
    	"Eclage Fields",F7, "Einbroch Fields",F8, "El Dicastes Fields",F9,
    	"Geffen Fields",F10, "Gonryun Fields",F11, "Hugel Fields",F12,
		"Lasagna Fields",F13, "Lighthalzen Fields",F14, "Louyang Field",F15, 
		"Lutie Field",F16, "Malaya Fields",F17, "Manuk Fields",F18, 
		"Mjolnir Fields",F19, "Moscovia Fields",F20, "Niflheim Fields",F21, 
		"Payon Forests",F22, "Prontera Fields",F23, "Rachel Fields",F24, 
		"Sograt Deserts",F25, "Splendide Fields",F26, "Umbala Fields",F27, 
		"Veins Fields",F28, "Yuno Fields",F29;

F1: setarray @c[2],190,197;
	Disp("Amatsu Field",1,1); Pick("ama_fild");
F2: setarray @c[2],173,134,212,150;
	Disp("Ayothaya Field",1,2); Pick("ayo_fild");
F3: Restrict("RE");
	setarray @c[2],193,220,220,187;
	Disp("Bifrost Field",1,2); Pick("bif_fild");
F4: Restrict("RE");
	setarray @c[2],74,32;
	Disp("Brasilis Field",1,1); Pick("bra_fild");
F5: Restrict("RE",5);
	setarray @c[2],180,178,231,160,191,172,228,194,224,203,190,223,234,177,194,175,172,172;
	Disp("Comodo Field",1,9); Pick("cmd_fild");
F6: Restrict("RE");
	setarray @c[2],371,212;
	Disp("Dewata Field",1,1); Pick("dew_fild");
F7: Restrict("RE");
	setarray @c[2],97,314;
	Disp("Eclage Field",1,1); Pick("ecl_fild");
F8: Restrict("RE",2,10);
	setarray @c[2],142,225,182,141,187,228,185,173,216,173,195,148,272,220,173,214,207,174,196,200;
	Disp("Einbroch Field",1,10); Pick("ein_fild");
F9: Restrict("RE");
	setarray @c[2],143,132,143,217;
	Disp("El Dicastes Field",1,2); Pick("dic_fild");
F10: Restrict("RE",2,10,13,14,15);
	 setarray @c[0],46,199,213,204,195,212,257,192,188,171,166,263,248,158,195,191,186,183,221,117,178,218,136,328,240,181,235,235,211,185;
	 Disp("Geffen Field",0,14); Pick("gef_fild",1);
F11: setarray @c[2],220,227;
	 Disp("Gonryun Field",1,1); Pick("gon_fild");
F12: Restrict("RE",3,7);
	 setarray @c[2],268,101,222,193,232,185,252,189,196,106,216,220,227,197;
	 Disp("Hugel Field",1,7); Pick("hu_fild");
F13: Restrict("RE");
	 setarray @c[2],344,371,20,98;
	 Disp("Lasagna Field",1,2); Pick("lasa_fild");	 
F14: setarray @c[2],240,179,185,235,240,226;
	 Disp("Lighthalzen Field",1,3); Pick("lhz_fild");
F15: setarray @c[2],229,187;
	 Disp("Louyang Field",1,1); Pick("lou_fild");
F16: Restrict("RE",1);
	setarray @c[2],115,145;
	 Disp("Lutie Field",1,1); Pick("xmas_fild");
F17: Restrict("RE");
	 setarray @c[2],40,272,207,180;
	 Disp("Malaya Field",1,2); Pick("ma_fild");
F18: setarray @c[2],35,236,35,262,84,365;
	 Disp("Manuk Field",1,3); Pick("man_fild");
F19: Restrict("RE",4);
	setarray @c[2],204,120,175,193,208,213,179,180,181,240,195,270,235,202,188,215,205,144,245,223,180,206,196,208;
	 Disp("Mjolnir Field",1,12); Pick("mjolnir_");
F20: setarray @c[2],82,104,131,147;
	 Disp("Moscovia Field",1,2); Pick("mosk_fild");
F21: setarray @c[2],215,229,167,234;
	 Disp("Niflheim Field",1,2); Pick("nif_fild");
F22: Restrict("RE",5,11);
	 setarray @c[2],158,206,151,219,205,148,186,247,134,204,193,235,200,177,137,189,201,224,160,205,194,150;
	 Disp("Payon Forest",1,11); Pick("pay_fild");
F23: setarray @c[0],208,227,190,206,240,206,190,143,307,252,239,213,185,188,193,194,187,218,210,183,195,149,198,164;
	 Disp("Prontera Field",0,11); Pick("prt_fild",1);
F24: Restrict("RE",2,3,4,7,9,10,11,13);
	 setarray @c[2],192,162,235,166,202,206,202,208,225,202,202,214,263,196,217,201,87,121,277,181,221,185,175,200,174,197;
	 Disp("Rachel Field",1,13); Pick("ra_fild");

F25: Restrict("RE",12,13,14);
	setarray @c[2],219,205,177,206,194,182,224,170,198,216,156,187,185,263,206,228,208,238,209,223,85,97,207,202,31,195,38,195;
	 Disp("Sograt Desert 1:Sograt Desert 2:Sograt Desert 3:Sograt Desert 7:Sograt Desert 11:Sograt Desert 12:Sograt Desert 13:Sograt Desert 16:Sograt Desert 17:Sograt Desert 18:Sograt Desert 19:Sograt Desert 20"); //:Sograt Desert 21:Sograt Desert 22"
	 Pick("","moc_fild01","moc_fild02","moc_fild03","moc_fild07","moc_fild11","moc_fild12","moc_fild13","moc_fild16","moc_fild17","moc_fild18","moc_fild19","moc_fild20"); //,"moc_fild21","moc_fild22"
F26: setarray @c[2],175,186,236,184,188,204;
	 Disp("Splendide Field",1,3); Pick("spl_fild");
F27: setarray @c[2],217,206,223,221,237,215,202,197;
	 Disp("Umbala Field",1,4); Pick("um_fild");
F28: Restrict("RE",1,2,5);
	 setarray @c[2],186,175,196,370,222,45,51,250,202,324,150,223,149,307;
	 Disp("Veins Field",1,7); Pick("ve_fild");
F29: Restrict("Pre-RE",5,10);
	 setarray @c[2],189,224,192,207,221,157,226,199,223,177,187,232,231,174,196,203,183,214,200,124,195,226,210,304;
	 Disp("Yuno Field",1,12); Pick("yuno_fild");

// --------------------------------------------------
	Dungeons:
// --------------------------------------------------
@d = true;
menu	"Abyss Lakes",D1, "Amatsu Dungeon",D2, "Anthell",D3,
    	"Ayothaya Dungeon",D4, "Beach Dungeon",D5, "Bifrost Tower",D42,
    	"Bio Labs",D6, "Brasilis Dungeon",D7, "Byalan Dungeon",D8, "Clock Tower",D9,
    	"Coal Mines",D10, "Culvert",D11, "Cursed Abbey",D12, "Dewata Dungeon",D13,
    	"Einbroch Dungeon",D14, "Gefenia",D15, "Geffen Dungeon",D16,
    	"Glast Heim",D17, "Gonryun Dungeon",D18, "Hidden Dungeon",D19,
    	"Ice Dungeon",D20, "Juperos",D21, "Kiel Dungeon",D22, "Lasagna Dungeon",D23,
		"Louyang Dungeon",D24, "Magma Dungeon",D25, "Malangdo Dungeon",D26,
		"Moscovia Dungeon",D27, "Nidhogg's Dungeon",D28, "Odin Temple",D29,
		"Orc Dungeon",D30, "Payon Dungeon",D31, "Pyramids",D32, "Rachel Sanctuary",D33,
    	"Scaraba Hole",D34, "Sphinx",D35, "Sunken Ship",D36, "Thanatos Tower",D37,
    	"Thor Volcano",D38, "Toy Factory",D39, "Turtle Dungeon",D40, "Umbala Dungeon",D41;

D1: Restrict("RE",3);
	setarray @c[2],261,272,275,270,116,27;
	Disp("Abyss Lakes",1,3); Pick("abyss_");
D2: Restrict("RE",3);
	setarray @c[2],228,11,34,41,119,14;
	Disp("Amatsu Dungeon",1,3); Pick("ama_dun");
D3: Restrict("RE",2);
	setarray @c[2],35,262,168,170;
	Disp("Anthell",1,2); Pick("anthell");
D4: Restrict("RE",2);
	setarray @c[2],275,19,24,26;
	Disp("Ancient Shrine Maze:Inside Ancient Shrine"); Pick("ayo_dun");
D5: Restrict("RE",1);
	setarray @c[2],266,67,255,244,23,260;
	Disp("Beach Dungeon",1,3); Pick("","beach_dun","beach_dun2","beach_dun3");
D6: Restrict("RE",3,4);
	setarray @c[2],150,288,150,18,140,134,244,52;
	Disp("Bio Lab",1,4); Pick("lhz_dun");
D7: Restrict("RE");
	setarray @c[2],87,47,262,262;
	Disp("Brasilis Dungeon",1,2); Pick("bra_dun");
D8: Restrict("RE",6);
	setarray @c[0],168,168,253,252,236,204,32,63,26,27,141,187;
	Disp("Byalan Dungeon",1,6); Pick("iz_dun",1);
D9: setarray @c[2],199,159,148,283,65,147,56,155,297,25,127,169,277,178,268,74;
	Disp("Clock Tower 1:Clock Tower 2:Clock Tower 3:Clock Tower 4:Basement 1:Basement 2:Basement 3:Basement 4");
	Pick("","c_tower1","c_tower2","c_tower3","c_tower4","alde_dun01","alde_dun02","alde_dun03","alde_dun04");
D10: setarray @c[2],52,17,381,343,302,262;
	 Disp("Coal Mines",1,3); Pick("mjo_dun");
D11:Restrict("RE",4);
	setarray @c[2],131,247,19,19,180,169,100,92;
	 Disp("Culvert",1,4); Pick("","prt_sewb1","prt_sewb2","prt_sewb3","prt_sewb4");
D12: Restrict("RE",2);
	setarray @c[2],51,14,150,11,120,10;
	 Disp("Cursed Abbey",1,3); Pick("abbey");
D13: Restrict("RE");
	 setarray @c[2],285,160,299,29;
	 Disp("Dewata Dungeon",1,2); Pick("dew_dun");
D14: Restrict("RE",2);
	setarray @c[2],22,14,292,290;
	 Disp("Einbroch Dungeon",1,2); Pick("ein_dun");
D15: setarray @c[2],40,103,203,34,266,168,130,272;
	 Disp("Gefenia",1,4); Pick("gefenia",0);
D16: Restrict("RE",1,2);
	setarray @c[0],104,99,115,236,106,132,203,200;
	 Disp("Geffen Dungeon",1,4); Pick("gef_dun",1);
D17: Restrict("RE",6);
	setarray @c[2],199,290,199,29,104,25,150,15,157,287,147,15,258,255,108,291,171,283,68,277,156,7,12,7,133,271,224,274,14,70,150,14;
	 Disp("Entrance:Castle 1:Castle 2:Chivalry 1:Chivalry 2:Churchyard:Culvert 1:Culvert 2:Culvert 3:Culvert 4:St. Abbey:Staircase Dungeon:Underground Cave 1:Underground Cave 2:Underground Prison 1:Underground Prison 2");
	 Pick("","glast_01","gl_cas01","gl_cas02","gl_knt01","gl_knt02","gl_chyard","gl_sew01","gl_sew02","gl_sew03","gl_sew04","gl_church","gl_step","gl_dun01","gl_dun02","gl_prison","gl_prison1");
D18: Restrict("RE",3);
	setarray @c[2],153,53,28,113,68,16;
	 Disp("Gonryun Dungeon",1,3); Pick("gon_dun");
D19: Restrict("RE",3);
	setarray @c[2],176,7,93,20,23,8;
	 Disp("Hidden Dungeon",1,3); Pick("prt_maze");
D20: Restrict("RE",3);
	setarray @c[2],157,14,151,155,149,22,33,158;
	 Disp("Ice Dungeon",1,4); Pick("ice_dun");
D21: Restrict("RE",4);
	setarray @c[2],140,51,53,247,37,63,150,285;
	 Disp("Entrance:Juperos 1:Juperos 2:Core");
	 Pick("","jupe_cave","juperos_01","juperos_02","jupe_core");
D22: Restrict("RE",2);
	setarray @c[2],28,226,41,198;
	 Disp("Kiel Dungeon",1,2); Pick("kh_dun");
D23: Restrict("RE");
	 setarray @c[2],24,143,22,171,190,18;
	 Disp("Lasagna Dungeon",1,3); Pick("lasa_dun");
D24: Restrict("RE",3);
	setarray @c[2],218,196,282,20,165,38;
	 Disp("The Royal Tomb:Inside the Royal Tomb:Suei Long Gon"); Pick("lou_dun");
D25: setarray @c[2],126,68,47,30;
	 Disp("Magma Dungeon",1,2); Pick("mag_dun");
D26: Restrict("RE");
	 setarray @c[2],33,230;
	 Disp("Malangdo Dungeon",1,1); Pick("mal_dun");
D27: Restrict("RE",3); 
	setarray @c[2],189,48,165,30,32,135;
	 Disp("Moscovia Dungeon",1,3); Pick("mosk_dun");
D28: setarray @c[2],61,239,60,271;
	 Disp("Nidhogg's Dungeon",1,2); Pick("nyd_dun");
D29: Restrict("RE",3); 
	 setarray @c[2],298,167,224,149,266,280;
	 Disp("Odin Temple",1,3); Pick("odin_tem");
D30: setarray @c[2],32,170,21,185;
	 Disp("Orc Dungeon",1,2); Pick("orcsdun");
D31:Restrict("RE",5);
	setarray @c[0],21,183,19,33,19,63,155,159,201,204;
	 Disp("Payon Dungeon",1,5); Pick("pay_dun",1);
D32: Restrict("RE",4,6,7,8);
	 setarray @c[2],192,9,10,192,100,92,181,11,94,96,192,8,94,96,192,8;
	 Disp("Pyramids 1:Pyramids 2:Pyramids 3:Pyramids 4:Basement 1:Basement 2:Basement 1 - Nightmare Mode:Basement 2 - Nightmare Mode");
	 Pick("","moc_pryd01","moc_pryd02","moc_pryd03","moc_pryd04","moc_pryd05","moc_pryd06","moc_prydn1","moc_prydn2");
D33: Restrict("RE",5);
	setarray @c[2],140,11,32,21,8,149,204,218,150,9;
	 Disp("Rachel Sanctuary",1,5); Pick("ra_san");
D34: Restrict("RE");
	 setarray @c[2],364,44,101,141;
	 Disp("Scaraba Hole",1,2); Pick("dic_dun");
D35: Restrict("RE",5);
	setarray @c[2],288,9,149,81,210,54,10,222,100,99;
	 Disp("Sphinx",1,5); Pick("","in_sphinx1","in_sphinx2","in_sphinx3","in_sphinx4","in_sphinx5");
D36: Restrict("RE",2);
	setarray @c[2],69,24,102,27;
	 Disp("Sunken Ship",1,2); Pick("treasure");
D37: setarray @c[2],150,39,150,136,220,158,59,143,62,11,89,221,35,166,93,148,29,107,159,138,19,20,130,52;
	 Disp("Thanatos Tower",1,12); Pick("tha_t");
D38: Restrict("RE",3);
	setarray @c[2],21,228,75,205,34,272;
	 Disp("Thor Volcano",1,3); Pick("thor_v");
D39: Restrict("RE",2);
	setarray @c[2],205,15,129,133;
	 Disp("Toy Factory",1,2); Pick("xmas_dun");
D40: Restrict("RE",4);
	setarray @c[2],154,49,148,261,132,189,100,192;
	 Disp("Entrance:Turtle Dungeon 1:Turtle Dungeon 2:Turtle Dungeon 3"); Pick("tur_dun");
D41: Restrict("RE",1,2);
	 setarray @c[2],42,31,48,30,204,78;
	 Disp("Carpenter's Shop in the Tree:Passage to a Foreign World:Hvergermil's Fountain");
	 Pick("","um_dun01","um_dun02","yggdrasil01");
D42: Restrict("RE");
	 setarray @c[2],57,13,64,88,45,14,26,23;
	 Disp("Bifrost Tower",1,4); Pick("ecl_tdun");

// --------------------------------------------------
	Castles:
// --------------------------------------------------
menu	"[FE] Aldebaran Castles",C1, "[FE] Geffen Castles",C2, "[FE] Payon Castles",C3,
    	"[FE] Prontera Castles",C4, "[SE] Arunafeltz Castles",C5, "[SE] Schwaltzvalt Castles",C6,
		"[TE] Aldebaran Castles",C7, "[TE] Prontera Castles",C8;

C1: setarray @c[2],48,83,95,249,142,85,239,242,264,90;
	Disp("Neuschwanstein:Hohenschwangau:Nuenberg:Wuerzburg:Rothenburg");
	Pick("","alde_gld","alde_gld","alde_gld","alde_gld","alde_gld");
C2: setarray @c[2],214,75,308,240,143,240,193,278,305,87;
	Disp("Repherion:Eeyolbriggar:Yesnelph:Bergel:Mersetzdeitz");
	Pick("","gef_fild13","gef_fild13","gef_fild13","gef_fild13","gef_fild13");
C3: setarray @c[2],121,233,295,116,317,293,140,160,204,266;
	Disp("Bright Arbor:Scarlet Palace:Holy Shadow:Sacred Altar:Bamboo Grove Hill");
	Pick("","pay_gld","pay_gld","pay_gld","pay_gld","pay_gld");
C4: setarray @c[2],134,65,240,128,153,137,111,240,208,240;
	Disp("Kriemhild:Swanhild:Fadhgridh:Skoegul:Gondul");
	Pick("","prt_gld","prt_gld","prt_gld","prt_gld","prt_gld");
C5: setarray @c[2],158,272,83,47,68,155,299,345,292,107;
	Disp("Mardol:Cyr:Horn:Gefn:Banadis");
	Pick("","aru_gld","aru_gld","aru_gld","aru_gld","aru_gld");
C6: setarray @c[2],293,100,288,252,97,196,137,90,71,315;
	Disp("Himinn:Andlangr:Viblainn:Hljod:Skidbladnir");
	Pick("","sch_gld","sch_gld","sch_gld","sch_gld","sch_gld");
C7: Restrict("RE");
	setarray @c[2],48,83,95,249,142,85,239,242,264,90;
	Disp("Kafragarten 1:Kafragarten 2:Kafragarten 3:Kafragarten 4:Kafragarten 5");
	Pick("","te_alde_gld","te_alde_gld","te_alde_gld","te_alde_gld","te_alde_gld");
C8: Restrict("RE");
	setarray @c[2],134,65,240,128,153,137,111,240,208,240;
	Disp("Gloria 1:Gloria 2:Gloria 3:Gloria 4:Gloria 5");
	Pick("","te_prt_gld","te_prt_gld","te_prt_gld","te_prt_gld","te_prt_gld");
	
// --------------------------------------------------
	Guild_Dungeons:
// --------------------------------------------------
menu	"Baldur",G1, "Luina",G2, "Valkyrie",G3, "Britoniah",G4,
    	"Arunafeltz",G5, "Schwaltzvalt",G6, "Kafragarten",G7,
		"Gloria",G8;

G1: Restrict("RE",2,3);
	setarray @c[2],119,93,119,93,120,130;
	Disp("Baldur F1:Baldur F2:Hall of Abyss");
	Pick("","gld_dun01","gld_dun01_2","gld2_pay");
G2: Restrict("RE",2,3);
	setarray @c[2],39,161,39,161,147,155;
	Disp("Luina F1:Luina F2:Hall of Abyss");
	Pick("","gld_dun02","gld_dun02_2","gld2_ald");
G3: Restrict("RE",2,3);
	setarray @c[2],50,44,50,44,140,132;
	Disp("Valkyrie F1:Valkyrie F2:Hall of Abyss");
	Pick("","gld_dun03","gld_dun03_2","gld2_prt");
G4: Restrict("RE",2,3);
	setarray @c[2],116,45,116,45,152,118;
	Disp("Britoniah F1:Britoniah F2:Hall of Abyss");
	Pick("","gld_dun04","gld_dun04_2","gld2_gef");
G5: Go("arug_dun01",199,195);
G6: Go("schg_dun01",200,124);
G7: Restrict("RE");
	Go("teg_dun01",42,36);
G8: Restrict("RE");
	Go("teg_dun02",26,160);

// --------------------------------------------------
	Instances:
// --------------------------------------------------
menu	"Bakonawa Lake",I1, "Bangungot Hospital 2F",I2, "Buwaya Cave",I3,
		"Devil Tower",I4, "Eclage Interior",I5, "Endless Tower",I6,
		"Faceworms Nest",I7, "Geffen Magic Tournament",I8, "Ghost Palace",I9,
		"Hazy Forest",I10, "Horror Toy Factory",I11, "Malangdo Culvert",I12,
		"Nidhoggur's Nest",I13, "Octopus Cave",I14, "Old Glast Heim",I15,
		"Orc's Memory",I16, "Sarah and Fenrir",I17, "Sara Memory",I18,
		"Sealed Shrine",I19, "Wolfchev's Laboratory",I20;

I1: Restrict("RE");
	Go("ma_scene01",172,175);
I2: Restrict("RE");
	Go("ma_dun01",151,8);
I3: Restrict("RE");
	Go("ma_fild02",316,317);
I4: Restrict("RE");
	Go("dali02",137,115);
I5: Restrict("RE");
	Go("ecl_hub01",129,12);
I6: Go("e_tower",72,112);
I7: Restrict("RE");
	Go("dali",85,64);
I8: Restrict("RE");
	Go("dali",94,141);
I9: Restrict("RE");
	Go("dali02",46,128);
I10: Restrict("RE");
	Go("bif_fild01",161,334);
I11: Restrict("RE");
	Go("xmas",234,298);
I12: Restrict("RE");
	Go("mal_in01",164,21);
I13: Go("nyd_dun02",95,193);
I14: Restrict("RE");
	Go("mal_dun01",152,230);
I15: Restrict("RE");
	Go("glast_01",204,268);
I16: Go("gef_fild10",240,198);
I17: Restrict("RE");
	Go("dali02",92,141);
I18: Restrict("RE");
	Go("dali",133,108);
I19: Go("monk_test",306,143);
I20: Restrict("RE");
	Go("lhz_dun04",148,269);

// --------------------------------------------------
	Special:
// --------------------------------------------------
menu	"Auction Hall",S1, "Battlegrounds",S2, "Casino",S3, "Dimensional Rift",S4,
		"Eden Group Headquarters",S5, "Gonryun Arena",S6, "Izlude Arena",S7, 
		"Monster Race Arena",S8, "Para Market",S9, "Turbo Track",S10;

S1: Go("auction_01",22,68);
S2: Go("bat_room",154,150);
S3: Go("cmd_in02",179,129);
S4: Restrict("RE");
	Go("dali",113,82);	
S5: Restrict("RE");
	Go("moc_para01",31,14);
S6: Go("gon_test",48,10);
S7: Go("arena_room",100,88);
S8: Go("p_track01",62,41);
S9: Restrict("RE");
	Go("paramk",97,17);
S10: Go("turbo_room",99,114);

OnInit:
	.Satan_Morroc = false;	//	false will enable moc_fild 4,5,6,8,9,10,14,15 while disable moc_fild 20,21,22 Default is true.
	.OnlyFirstFld = false;	//	true will teleport to the first level of the Fields  Default is false.
	.OnlyFirstDun = false;	//	true will teleport to the first level of the Dungeons  Default is false.
}
alb2trea,57,70,6	duplicate(Warper)	Warper#tre	4_F_VALKYRIE
alberta,28,240,4	duplicate(Warper)	Warper#alb	4_F_VALKYRIE
aldebaran,145,118,4	duplicate(Warper)	Warper#alde	4_F_VALKYRIE
amatsu,203,87,4	duplicate(Warper)	Warper#ama	4_F_VALKYRIE
ayothaya,209,169,6	duplicate(Warper)	Warper#ayo	4_F_VALKYRIE
comodo,194,158,4	duplicate(Warper)	Warper#com	4_F_VALKYRIE
einbech,59,38,6	duplicate(Warper)	Warper#einbe	4_F_VALKYRIE
einbroch,69,202,4	duplicate(Warper)	Warper#einbr	4_F_VALKYRIE
//gef_fild10,71,339,4	duplicate(Warper)	Warper#orc	4_F_VALKYRIE
geffen,124,74,4	duplicate(Warper)	Warper#gef	4_F_VALKYRIE
//glast_01,372,308,4	duplicate(Warper)	Warper#glh	4_F_VALKYRIE
gonryun,162,122,4	duplicate(Warper)	Warper#gon	4_F_VALKYRIE
hugel,101,151,4	duplicate(Warper)	Warper#hug	4_F_VALKYRIE
//izlu2dun,110,92,4	duplicate(Warper)	Warper#izd	4_F_VALKYRIE
izlude,132,120,4	duplicate(Warper)	Warper#izl	4_F_VALKYRIE	//Pre-RE: (132,120)
jawaii,253,138,4	duplicate(Warper)	Warper#jaw	4_F_VALKYRIE
lighthalzen,162,102,4	duplicate(Warper)	Warper#lhz	4_F_VALKYRIE
louyang,208,103,6	duplicate(Warper)	Warper#lou	4_F_VALKYRIE
manuk,274,146,6	duplicate(Warper)	Warper#man	4_F_VALKYRIE
mid_camp,216,288,4	duplicate(Warper)	Warper#mid	4_F_VALKYRIE
//mjolnir_02,85,364,4	duplicate(Warper)	Warper#mjo	4_F_VALKYRIE
moc_ruins,64,164,4	duplicate(Warper)	Warper#moc	4_F_VALKYRIE
morocc,159,97,4	duplicate(Warper)	Warper#mor	4_F_VALKYRIE
moscovia,229,191,4	duplicate(Warper)	Warper#mos	4_F_VALKYRIE
//nameless_n,259,213,4	duplicate(Warper)	Warper#nam	4_F_VALKYRIE
niflheim,205,179,4	duplicate(Warper)	Warper#nif	4_F_VALKYRIE
pay_arche,42,134,4	duplicate(Warper)	Warper#arc	4_F_VALKYRIE
payon,182,108,4	duplicate(Warper)	Warper#pay	4_F_VALKYRIE
prontera,160,192,4	duplicate(Warper)	Warper#prt	4_F_VALKYRIE
//prt_fild05,279,223,6	duplicate(Warper)	Warper#cul	4_F_VALKYRIE
rachel,135,116,4	duplicate(Warper)	Warper#rac	4_F_VALKYRIE
splendide,205,153,4	duplicate(Warper)	Warper#spl	4_F_VALKYRIE
thor_camp,249,76,4	duplicate(Warper)	Warper#thor	4_F_VALKYRIE
umbala,106,150,3	duplicate(Warper)	Warper#umb	4_F_VALKYRIE
veins,214,123,4	duplicate(Warper)	Warper#ve	4_F_VALKYRIE
xmas,150,136,6	duplicate(Warper)	Warper#xmas	4_F_VALKYRIE
yuno,162,47,4	duplicate(Warper)	Warper#yuno	4_F_VALKYRIE

// --------------------------------------------------
//	Duplicates (Renewal):
// --------------------------------------------------
brasilis,201,222,4	duplicate(Warper)	Warper#bra	4_F_VALKYRIE
dewata,204,186,6	duplicate(Warper)	Warper#dew	4_F_VALKYRIE
dicastes01,194,194,6	duplicate(Warper)	Warper#dic	4_F_VALKYRIE
ecl_in01,51,60,4	duplicate(Warper)	Warper#ecl	4_F_VALKYRIE
malangdo,134,117,6	duplicate(Warper)	Warper#mal	4_F_VALKYRIE
malaya,231,204,4	duplicate(Warper)	Warper#ma	4_F_VALKYRIE
mora,57,152,4	duplicate(Warper)	Warper#mora	4_F_VALKYRIE

     

×
×
  • Create New...

Important Information

By using this site, you agree to our Terms of Use.

  I accept