Npc which sell refined Equipments

[caspe 16]

Hello, i want npc which sells +7 refined equipment like +7 wool scarf and tidal shoes for defined currency like Gold Coin.

 

OR

 

It is possible to add new item in item_db which is already +7?

[Alayne 99]

Can't test it, but this should do the job.

prontera,155,155,4	script	Refined Shop::alresho	4_F_06,{
	set .@npcname$, "[Refined Shop]";
	mes .@npcname$;
	mes "Hello to you!";
	mes "I can sell you some allready refined stuffs.";
	mes "Interested?";
	set .@menu$, "";
	for(set .@i,0; .@i<getarraysize(.stuffIds); set .@i,.@i+1)
	{
		set .@menu$, .@menu$ + (.@i == 0 ? "" : ":") + getitemname(.stuffIds[.@i]);
	}
	set .@choice, select(.@menu$) - 1;
	next;
	mes .@npcname$;
	mes "We're going for a " + getitemname(.stuffIds[.@choice]) + ", right?";
	mes "It'll cost you " + .price[.@choice] + " " + getitemname(.currency) + ", ok?";
	if(select("Yes","No") == 1)
	{
		if(countitem(.currency) >= .price[.@choice])
		{
			delitem .currency, .price[.@choice];
			getitem2 .stuffIds[.@choice], 1, 1, 7, 0, 0, 0, 0, 0;
		}
		next;
		mes .@npcname$;
		mes "Right! See you!";
	}
	close;	
	
OnInit:
	setarray .stuffIds[0],2424,2528;
	setarray .price[0],1,2;
	set .currency, 512;
	end;
}

Tell me if there's an issue.

[bWolfie 138]

I remember there is a plugin that does this. If I recall, it is sellitem2: https://github.com/dastgir/HPM-Plugins

[Dastgir 1246]

4 hours ago, Myriad said:

I remember there is a plugin that does this. If I recall, it is sellitem2: https://github.com/dastgir/HPM-Plugins

though it accepts zeny only and not item.